• tixDirList
• tixDisplayStyle
• tixScrolledWindow
• tixDirTree

●ディレクトリリスト
　ディレクトリリストは、ハイアラキカルリストを発展させたウィジェットです。 形状はかばんの絵がついただけですが、 最初からファイルシステムを走査してディレクトリ構造を表示する機能を持っています。 かばんの絵がちょっといまいちなのですが、 これはインストールディレクトリに含まれるビットマップを強引に書きかえれば自分の好みのアイコンに変えることもできます。 次の例は、実際に使える画像ビューアで、 スクリーンショット左上がディレクトリリストです。 ここで選択したディレクトリに含まれるファイルの一覧が右上のリストに表示され、 これをダブルクリックすると、選んだファイルが画像であればその内容を下のスクロールするキャンバスの中に表示します。

package require Tix
package require pife
wm title . "Image Viewer"

tixDisplayStyle text -stylename redstyle -fg #800040
tixDisplayStyle text -stylename redrightstyle -fg #800040 -anchor e
tixDisplayStyle text -stylename rightstyle -anchor e

# 画面左上、ディレクトリリストを作ります。
# tixDirListの-width -heightはピクセル数です。
# またhlistサブウィジェットのデフォルト背景色は灰色です。
set da [tixDirList .da -root /]
$da subwidget hlist configure -bg white

# 画面右上、ファイルリストを作ります。
# tixScrolledHListは複数のカラムをつけることができません。
# そこで、通常のtixHListとスクロールバーを使います。
set fa [frame .fa]
set ha [tixHList $fa.ha -column 2 -separator / -width 50 \
        -xsc "$fa.scrh set" -ysc "$fa.scrv set"]
scrollbar $fa.scrv -ori v -command "$ha yview"
scrollbar $fa.scrh -ori h -command "$ha xview"
grid $ha -row 1 -col 1
grid $fa.scrv -row 1 -col 2 -sticky ns
grid $fa.scrh -row 2 -col 1 -sticky ew

$ha col width 0 -char 15
$ha col width 1 -char  8

# 画面下、画像表示部分を作ります。
# tixScrolledWindow
set sw [tixScrolledWindow .sw -width 450 -height 200]
set swf [$sw subwidget window]
canvas $swf.can -width 300 -height 300 -bg white
pack $swf.can

# コールバックの登録
$da configure -browsecmd "CBdirselected $ha"
$ha configure -command   "CBfileselected $da $ha $swf.can"

# ファイルが選択されたときのコールバックプロシージャ。
# 下のキャンバスに画像を表示します。
proc CBfileselected {dlist hlist can filename} {
    # tixDirListから現在選択されているディレクトリの絶対パスを得るには
    # -valueオプションを使います。
    set dname [$dlist cget -value]
    set filename [file join $dname $filename]
    if {[catch {
        $hlist configure -cursor watch; update
	image create photo Image1 -file $filename
    }]} {
	$hlist configure -cursor {}; update; return
    }
    $can delete all
    $can create image 0 0 -anc nw -image Image1
    $can configure -width [image width Image1] -height [image height Image1]
    $hlist configure -cursor {}; update
}

# tixDirListがシングルクリックされたときのコールバックプロシージャ。
# 選択されているディレクトリの絶対パスが自動的に引数につけられます。
proc CBdirselected {hlist absdirpath} {
    set entries [glob -nocomplain [file join $absdirpath *]]
    set imageexts {.bmp .gif .jpg .tif .tiff .png .xpm}

    # tixHListの項目をクリア
    $hlist delete all

    # ファイル名を追加します。tixHListの「階層」機能は使わず、
    # 単に縦横に項目を並べるために使っています。
    foreach fullpath $entries {
        set e [file tail $fullpath]
	$hlist add $e -itemtype text -text $e
        $hlist item create $e 1 -itemtype text \
          -text [file size $fullpath] -style rightstyle
        # もしファイルが画像っぽい拡張子をもっていたら、赤で目立たせます。
        if {[lsearch $imageexts [file extension $e]] != -1} {
	    $hlist item configure $e 0 -style redstyle
	    $hlist item configure $e 1 -style redrightstyle
	}
    }
}

grid $da -row 1 -col 1
grid $fa -row 1 -col 2
grid $sw -row 2 -col 1 -columnspan 2

●ディスプレイスタイル
　ディスプレイスタイルは、TixでのGUIを習得するうえで重要な概念ですが、 ウィジェットではありません。Tixのウィジェットのうち、

• tixGridのセル
• tixHList、tixTList、tixTree、tixDirList、tixDirTreeの項目

tixDisplayStyle text -stylename redrightstyle -fg #800040 -anchor e
# ...
$hlist item configure $e 1 -style redrightstyle

set redright [tixDisplayStyle text -fg #800040 -anchor e]
# ...
$hlist item configure $e 1 -style $redright

●スクロールドウィンドウ
　標準Tkで、ウィンドウの大きさを超えるキャンバスやフレームなどを作り、 スクロールバーによってスクロールできるようにすることは可能ですが、 毎回かなりの量の決まったコードを書かなくてはいけません。 Tixのスクロールドウィンドウはフレームとスクロールバーを自動的に用意してくれるウィジェットで、 後はスクロールさせたい中身を載せるだけという所までお膳立てをしてくれます。

set sw [tixScrolledWindow .sw -width 450 -height 200]
set swf [$sw subwidget window]
canvas $swf.can -width 300 -height 300 -bg white
pack $swf.can

●ディレクトリツリー
　ありゃ？ディレクトリリストの他にディレクトリツリーなるウィジェットもあるというのはどういうことかしら？ とりあえず、サンプルをご紹介することにしましょう。 これは手前みそですが、 DPU拡張で追加している「magic」(ファイル名からそのファイルの種類を推測して返すコマンド) を使った簡単なツールです。 左半分がディレクトリツリーです。ここでどれかのディレクトリをつつくと、 そのディレクトリに含まれるファイルのリストが右に現れ、 その怪しげなmagicコマンドでファイルの種類を推測した内容が表示されます。

package require Tix
package require dpu

set trea [tixDirTree .trea \
  -browsecmd "CBDirTreeClicked .f2.ha" -directory C:/Install \
  -showhidden 1]
set f [frame .f2 -rel groove -bd 2]
set ha [tixHList $f.ha -separator . -header 1 -columns 2 \
        -yscrollcommand "$f.scrv set" -xscrollcommand "$f.scrh set" \
        -width 40]
scrollbar $f.scrv -ori v -command "$f.ha yview"
scrollbar $f.scrh -ori h -command "$f.ha xview"
grid $f.ha -row 1 -col 1
grid $f.scrv -row 1 -col 2 -sticky ns
grid $f.scrh -row 2 -col 1 -sticky ew

$ha header create 0 -text 名前
$ha header create 1 -text 種類

proc CBDirTreeClicked {ha dirpath} {
    set dirpath [lindex $dirpath 0]
    # 今の行を全て削除
    $ha delete all
    # エントリを追加
    set i 0
    foreach e [glob -nocomplain [file join $dirpath *]] {
	$ha add $i -itemtype text -text [file tail $e]
	if {[file isfile $e]} {
	    # 通常ファイルの場合、その説明を追加
	    if {[catch {set description [magic $e]}]} {
		set description "(cannot open)"
	    }
	    $ha item create $i 1 -text $description
	}
	incr i
    }
}

pack $trea $f -side left -fill y
# end.

set trea [tixDirTree .trea \
  -browsecmd "CBDirTreeClicked .f2.ha" -directory C:/Install \
  -showhidden 1]

proc CBDirTreeClicked {ha dirpath} {
    set dirpath [lindex $dirpath 0]
    # ...
}

(first uploaded 2001/04/22 last updated (not ever), MISUMI URANO)