TclXはTcl言語のみの拡張で、Tkに関する拡張はありません。 次のような機能が追加されています。

1. 再帰グロブなどの便利なコマンド
2. コマンドトレースなどのデバッグ機構
3. 便利なオンラインヘルプならぬランタイムヘルプ
4. シグナル、ファイル属性の操作などのUNIXシステムプログラミング
5. キーつきリスト

●インストールしよう
LinuxのSlackwareなどではOSのCD-ROMに入っていて、 簡単にインストールすることができます。 MS-Windows用にはダウンロードしてすぐに使えるバイナリとして配布されているようですが、そちらは当サイトではまだ試していません。 その他のUNIXマシンの場合は、 TclXのソースプログラムを入手してコンパイル→インストール作業が必要になります。 その際、同じバージョンのTclのソースプログラムの一部が必要になるので、 Tclのソースアーカイブを展開した同じディレクトリから、 TclXのソースアーカイブも展開しておきます。
コンパイル作業自体は下のように簡単です。

% sh configure
% make
% su root
# make install

●再帰グロブ
recursive_globは、UNIXのfindコマンドのように、 ディレクトリ構造を下へ下へと再帰的にファイルを探すコマンドです。 また、探しながら何かをするために for_recursive_globというforeachようの制御構造も用意されています。

recursive_globは、

    recursive_glob startdir_list glob_list 

    set files [recursive_glob . *.tcl]

for_recursive_globはその制御構造版です。 例えば、現在のディレクトリから下を検索し、*.tclという名前のファイルを全部調べ、 その中の 'require' という文字列が含まれる行を行番号つきで全部出力するには、 このようにします。これは便利ライオン。

    for_recursive_glob a {.} {*.tcl} {
	set fp [open $a r]
	for {set n 1} {! [eof $fp]} {incr n} {
	    set buf [gets $fp]
	    if {[regexp {require} $buf]} {
		puts "$a\[$n\]:$buf"
	    }
	}
	close $fp
    }

●コマンドのトレースとプロファイリング
プロファイリングといってもFBIの犯罪捜査ではないので大丈夫。 コマンドのトレースというのは、 Tclコマンドが何か実行されるたびにそのコマンドをログファイルに記録していく機能です。 またプロファイリングというのは、 Tclスクリプトを実行したさい、どのコマンドが何回実行されたか、 どの程度時間がかかったかを記録し、 レポートみたいな形でファイルに出してくれる機能です。 gprofなどのプロファイラを使ったことがある方にはおなじみですね。 これらはスクリプトのデバッグに役立ちます。
では何か既存のTclスクリプトに対してこいつらをかけてみます。

cmdtrace on [open cmd.log w]
profile -commands -eval on

source "freecell.tcl"; # 何か好きなファイルを

cmdtrace off
profile off ProfResult
profrep ProfResult calls prof.log

コマンドのトレース結果はcmd.logにこのように書き出されます。

 1:  profile -commands -eval on
 1:  lindex freecellunix.tcl 0
 1:  source freecellunix.tcl
 2:    namespace eval FreeCell {\n\nset ImageData(spade) { R0lGODdhEwATAPc...}
 3:      set ImageData(spade) { R0lGODdhEwATAPcAAAAAAAAAVQAAqgAA/wAkAAA...}
 3:      set CANVASWIDTH 380
 3:      set CANVASHEIGHT 380
 3:      clock seconds
 3:      expr srand(930965642)
 3:      proc ProgramInit {} {\nvariable Score\nset Score(win) 0; set ...}

プロファイリングの結果はprof.logにこのように書き出されます。

-----------------------------------------------------------------------------
Procedure Call Stack                              Calls  Real Time   CPU Time
-----------------------------------------------------------------------------
FreeCell::random                                    380        158        157
    FreeCell::Init
    source
return                                              380          0          0
    FreeCell::random
    FreeCell::Init
    source
llength                                             175         10         11
    FreeCell::Init
    source
list                                                156          0          0
    FreeCell::DrawCardAtCanvasLocationOf
    FreeCell::DrawAll
    FreeCell::Init
    source
...
...

●ランタイムヘルプ
TclXシェルの対話入力モードでは、 オンラインヘルプならぬランタイムヘルプが使えます。 helpというコマンドを使って、おもむろに

  tcl>help lappend

●UNIXシステムプログラミング
TclXには、ファイルの属性操作など高度なUNIXシステムプログラミング用のコマンドが大量に投入されていますが、 全部を使うことはないでしょう。スクリプト言語で頻繁に chrootやselectを使う人はあまりいないでしょうし。 そんな中でも若干使うか、 というのがsignalコマンドを使ったシグナル操作です。 シグナルを飛ばしたり、 シグナルの一種であるalarm機能を使ったりすることもできますが、 とりあえずシグナルの受け取りかたはこんな感じです。

# シグナルの番号は「SIGINT」「INT」「2」のどの形式でもOK
signal trap SIGINT trapINT
signal trap 15     trapTERM

proc trapINT {args} {
    tk_messageBox -message "SIGINT Trapped."
}
proc trapTERM {args} {
    tk_messageBox -message "SIGTERM Trapped."
}

label  .laba -text Hello
button .cmda -text {Send Any Signal} -command exit
pack .laba -side top
pack .cmda -side top

●ハローミスターパイプマン
TclXのUNIX版では、 UNIXで使えるシステムコールが同名のTclコマンドとして提供されています。 それらを(ちょっとだけ)駆使した例として、子プロセスを起動し、 標準入出力を相互につないでデータをやりとりするスクリプトをご紹介します。 せっかくなので、多少は実用になるスクリプトを作りたい、 ということで、子プロセスは下のようなPerlスクリプトにしてみました。 これは標準入力からサーバーマシンのホスト名またはIPアドレスを読み取り、 Perlのgethostbyaddr関数または gethostbyname関数を使って、 ホスト名ならIPアドレスに、 IPアドレスならホスト名に変換して標準出力に出力します。

#! /usr/local/bin/perl
chomp($s = <STDIN>);
if(/^\d/){
    ($a) = gethostbyaddr(pack("C*", split(/\./, $s)), 2);
} else {
    ($a) = join(".", unpack("C*", gethostbyname($s)));
}
print "[$a]\n";
# end.

#! /usr/local/bin/tclsh
package require Tclx

pipe fdin1 fdout1
pipe fdin2 fdout2

if {[fork] == 0} {
    dup $fdin1  stdin
    dup $fdout2 stdout
    set cmd "perl ./gethost.pl"
    eval execl $cmd
} else {
    set alt_stdout [dup stdout]
    dup $fdin2  stdin
    dup $fdout1 stdout
    fcntl stdout NONBLOCK 1
    fcntl stdout NOBUF    1

    puts "www.kantei.go.jp" ; # 話題の首相官邸をセレクト(ホントは適当)
    set buf [gets stdin]
    puts $alt_stdout "*** $buf ***"
    puts $alt_stdout "salvaged: [wait]"
}
# end.

●DNSによる名前解決(円満に)
そういえば、Perlにはgethostbyname やgethostbyaddrのような DNS(Domain Name Service)を利用してホスト名とIPアドレスの対応付け (名前解決)を行う関数がありますが、Tclにはその機能はないのでしょうか？ おお、ちょうどよいところにいらっしゃった！（仕組んだように） TclXにはそのようなコマンドが提供されているのでした。 すっかり忘れていましたな（やっぱり仕組んだように）

#! /usr/local/bin/tclsh
package require Tclx

while 1 {
    puts -nonewline ">"; flush stdout
    set a [gets stdin]
    if {[eof stdin]} break
    if {[regexp {^[[:digit:]]} $a]} {
        puts [host_info official_name $a]
    } else {
        puts [host_info addresses $a]
    }
}
# end.

(first uploaded 1999/07/03 last updated 2012/05/27, KAZUHISA ESHI - MISUMI URANO)